Condividi:        

piu' condizioni SE

Vuoi potenziare i tuoi documenti Word? Non sai come si fa una macro in Excel? Devi creare una presentazione in PowerPoint?
Oppure sei passato a OpenOffice e non sei sicuro di come lavorare al meglio?

Moderatori: Anthony47, Flash30005

piu' condizioni SE

Postdi raimea » 04/06/14 06:08

ciao
in un file vorrei riuscire a mettere una formula
con 9 condiz SE in una cella, la cella di COL T.

ho office 2003, e so' che arriva al max a 7 cond SE stessa formula.

vorrei un vostro consiglio suggerimento a come riuscire se possibile.

nel fgl -diario- ho messo uno specchietto che riassume tutti i casi
che andrebbero rispettati nella formula
che va scritto un celle della COL T da T6 in giu.

NB:
mi potrebbe andare bene anche una macro.


vi allego il file
https://db.tt/n9OOzypj

grazie
ciao
S.O. win10, Excell 2019
Avatar utente
raimea
Utente Senior
 
Post: 1410
Iscritto il: 11/02/10 07:33
Località: lago

Sponsor
 

Re: piu' condizioni SE

Postdi ninai » 04/06/14 08:09

sicuramente si potrà accorciare, ma seguendo esplicitamente la linea delle tue condizioni, senza eventuali "scorciatoie", verrebbe fuori questa:
=SE(O(K6=0;S6="");0;(J6="punta")*(N6="")*(S6="vinta")*M6+(J6="punta")*(N6="")*(S6="persa")*(I6-1)+(J6="banca")*(N6="")*(S6="vinta")*I6+(J6="banca")*(N6="")*(N6="persa")*(M6-1)+(J6="punta")*(N6="banca")*(S6="bancato")*((Q6-M6)-((Q6-M6)*$S$3))+(J6="banca")*(N6="punta")*(S6="puntato")*((M6-Q6)-((M6-Q6)*$S$3)))

in T6, da testare
w8 + Office 2010 Ita
ninai
Utente Senior
 
Post: 271
Iscritto il: 12/06/13 05:23
Località: prov. Messina

Re: piu' condizioni SE

Postdi raimea » 04/06/14 10:38

ciao
purtroppo al momento non va bene
prendi ES il risultato in T7 dovrebbe dare -7
invece la formula restituisce 0
ciao
S.O. win10, Excell 2019
Avatar utente
raimea
Utente Senior
 
Post: 1410
Iscritto il: 11/02/10 07:33
Località: lago

Re: piu' condizioni SE

Postdi Anthony47 » 04/06/14 11:27

Sia chiaro, in XL2003 (e precedenti) il limite non e' di 7 "SE", ma di 7 "funzioni qualsiasi" annidate (una interna all' altra); poi c' e' il limite di 1024 caratteri massimi per una formula.
Cio' detto, io userei in T6 la formula
Codice: Seleziona tutto
=SE(E(J6="Punta";N6="";S6="vinta");M6;0)+SE(E(J6="Punta";N6="";S6="persa");L6-1;0)+SE(etc etc)

Ho codificato le prime due condizioni; per le altre e' solo un gioco di pazienza...
Se vuoi complicarti la vita, puoi accorpare in un unico SE le prime due condizioni (e probabilmente anche le due successive):
Codice: Seleziona tutto
=SE(E(J6="Punta";N6="");se(S6="vinta";M6;se(S6="persa";L6-1;0));0)+SE(Etc etc)


Se ti da fastidio visualizzare lo "0", formatta le celle come "Personalizzato" usando come Tipo la stringa "€#,00;-€#,00;;@" (senza le virgolatte).

Ciao
Avatar utente
Anthony47
Moderatore
 
Post: 19196
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: piu' condizioni SE

Postdi raimea » 04/06/14 12:59

ciao
risolto , questa la formula finale:
Codice: Seleziona tutto
=SE(E(J6="Punta";N6="";S6="vinta");M6-(M6*$S$3);0)+SE(E(J6="Punta";N6="";S6="persa");L6*-1;0)+SE(E(J6="banca";N6="";S6="vinta");L6;0)+SE(E(J6="banca";N6="";S6="persa");M6*-1;0)+SE(E(J6="punta";N6="banca";S6="bancato");(M6-Q6)-(M6-Q6)*$S$3;0)+SE(E(J6="banca";N6="punta";S6="puntato");(Q6-M6)-(Q6-M6)*$S$3)


sembra una parolaccia... :D

e io che non sapevo di poter mettere il segno "+" tra un se e l'altro.... :roll:
non e' di 7 "SE", ma di 7 "funzioni qualsiasi" annidate (una interna all' altra

ero convinto che non si potevano mettere piu di 7 SE ... in generale...
quindi ho imparato anche oggi una cosa nuova

grazie
S.O. win10, Excell 2019
Avatar utente
raimea
Utente Senior
 
Post: 1410
Iscritto il: 11/02/10 07:33
Località: lago

Re: piu' condizioni SE

Postdi ninai » 04/06/14 17:44

giusto per la cronaca, l'errore nella mia formula era dovuto a delle mie sviste nella tabella delle condizioni: scambio della L con la I e di -1 invece che *-1, la formula corretta (tranne altre minchiate, non so quali sono i risultati voluti):
Codice: Seleziona tutto
=SE(O(K6=0;S6="");0;(J6="punta")*(N6="")*(S6="vinta")*M6+(J6="punta")*(N6="")*(S6="persa")*L6*-1+(J6="banca")*(N6="")*(S6="vinta")*L6+(J6="banca")*(N6="")*(N6="persa")*M6*-1+(J6="punta")*(N6="banca")*(S6="bancato")*(Q6-M6)*(1-$S$3)+(J6="banca")*(N6="punta")*(S6="puntato")*(M6-Q6)*(1-$S$3))



ho semplificato: (M6-Q6)*(1-$S$3)
invece che: ((m6-q6)-(m6-q6)*s3)
w8 + Office 2010 Ita
ninai
Utente Senior
 
Post: 271
Iscritto il: 12/06/13 05:23
Località: prov. Messina

Re: piu' condizioni SE

Postdi raimea » 04/06/14 17:58

ciao
ottimo :D
grazie
S.O. win10, Excell 2019
Avatar utente
raimea
Utente Senior
 
Post: 1410
Iscritto il: 11/02/10 07:33
Località: lago


Torna a Applicazioni Office Windows


Topic correlati a "piu' condizioni SE":


Chi c’è in linea

Visitano il forum: Nessuno e 47 ospiti

cron