Trasforma formula in matriciale

[Sasyjoe]

Ciao ragazzi,
ho un problemino difficile per me ma sicuramente facile per voi:

Ho 31 formule uguali, cambiano solo le celle di riferimento. Vorrei un'unica formula matriciale.
Le formule sono le seguenti

=SE(B112>2,5;1;SE(E(B112>0;B112<=2,5);0,5;0))
=SE(B113>2,5;1;SE(E(B113>0;B113<=2,5);0,5;0))
=SE(B114>2,5;1;SE(E(B114>0;B114<=2,5);0,5;0))
=SE(B115>2,5;1;SE(E(B115>0;B115<=2,5);0,5;0))
...................

=SE(B138>2,5;1;SE(E(B138>0;B138<=2,5);0,5;0))


Le formule sono 31. Nella cella sotto queste 31 formule, inserisco la formula SOMMA.
Mi occorrerebbe una formula che fa tutto questo in una sola formula matriciale.


Spero di essere stato chiaro. Grazieeeeee

[CANAPONE]

Ciao,

che versione di Excel hai a disposizione?

[CANAPONE]

Ciao,

ho visto che hai allegato un Excel 2007/2010 in un precedente intervento.

La matriciale non serve

Codice: Seleziona tutto

=CONTA.PIÙ.SE($B$112:$B$138;">0";$B$112:$B$138;"<=2,5")/2+CONTA.SE($B$112:$B$138;">2,5")

Mi sembra anche che potrebbe bastare:

Codice: Seleziona tutto

=(CONTA.SE($B$112:$B$138;">0")+CONTA.SE($B$112:$B$138;">2,5"))/2

Saluti

[Sasyjoe]

Grande Canapone.
Vanno bene entrambi.

approfitto del tuo sapere per lo stesso discorso ma sta volta penso ci voglia la matriciale:

ho 31 formule:

=SE(E(D79<>"";E79<>"";E79<=D79);1;0)
=SE(E(D80<>"";E80<>"";E80<=D80);1;0)
.....................
=SE(E(D105<>"";E105<>"";E105<=D105);1;0)

sotto ho una cella con SOMMA.

Mi occorrerebbe tutto in unica formula.
Grazie.

[CANAPONE]

Ciao,

una prima risposta

Codice: Seleziona tutto

=SOMMA(INDICE(--(D79:D105>=E79:E105)*(D79:D105<>"")*(E79:E105<>"");))

Migliorabile sicuramente

[Sasyjoe]

Dato che non voglio chiederti la formula per ogni mio problema sto provando a ricostruirmi la formula per altri passaggi simili ma non riesco.

Mi puoi spiegare perchè utilizzi "indice(--"

Grazie

[Sasyjoe]

Esempio di perche non riesco:

ho scritto questa:

=SOMMA(INDICE(--($B$112:$B$138>0)*($I$79:$I$105>0);))

Vorrei come risultato la SOMMA di queste:

=SE(B112>0;I79;0)
=SE(B113>0;I80;0)
..........
=SE(B138>0;I105;0)

cosa sbaglio?

[CANAPONE]

Ciao,

prova

Codice: Seleziona tutto

=SOMMA(INDICE(($B$112:$B$138>0)*$I$79:$I$105;))

Nella precedente formula i -- non fanno danni ma non servono: sono in di più.

Saluti

[CANAPONE]

Ciao di nuovo ,

...

Nella precedente formula i -- non fanno danni ma non servono: sono in di più. (...)

facevo riferimento a

Codice: Seleziona tutto

=SOMMA(INDICE(--(D79:D105>=E79:E105)*(D79:D105<>"")*(E79:E105<>"");))

dove i -- facevano giusto atto di presenza

Codice: Seleziona tutto

=SOMMA(INDICE((D79:D105>=E79:E105)*(D79:D105<>"")*(E79:E105<>"");))

Non mi sembrava chiaro quanto avevo scritto.

Saluti