Valutazione 4.87/ 5 (100.00%) 5838 voti

Condividi:        

Ho installato la XPSP2BlockerTools e adesso ho deciso...

Hai problemi con i file Zip, vuoi formattare l'HD, non sai come funziona FireFox? O magari ti serve proprio quel programmino di cui non ricordi il nome! Ecco il forum dove poter risolvere i tuoi problemi.

Moderatori: Dylan666, hydra, gahan

Ho installato la XPSP2BlockerTools e adesso ho deciso...

Postdi Locutus » 17/09/04 12:51

... di provare il SP2, windows update chiaramente non mi consente di installarla, come posso disintallare qusta patch che mi inibisce l'aggiornamento al SP2?

Superfluo dire la copia di XP in mio possesso è originale e che gli aggionamenti SP1 sono disponibili.

Grazie!!! ;)
Locutus
Utente Senior
 
Post: 402
Iscritto il: 24/03/02 20:38
Località: Torino

Sponsor
 

Re: Ho installato la XPSP2BlockerTools e adesso ho deciso...

Postdi Dylan666 » 19/09/04 05:31

Usa questo script (forse lo hai già fatto) copiandolo in un file di testo rinominato come blockxpsp2.vbs :

Codice: Seleziona tutto
' Copyright (c) Microsoft Corporation 2004
' File:       BlockXPSP2.vbs
' Contents:   Remotely blocks or unblocks the delivery of
' Windows XP SP2 from Windows Update web site or via Automatic
' Updates.
' History:    8/20/2004   Peter Costantini   Created
' Version:    1.0

On Error Resume Next

' Define constants and global variables.
Const HKEY_LOCAL_MACHINE = &H80000002
strComputer = "." ' Can be changed to name of remote computer.
strKeyPath = "Software\Policies\Microsoft\Windows\WindowsUpdate"
strEntryName = "DoNotAllowXPSP2"
dwValue = 1

' Handle command-line arguments.
Set colArgs = WScript.Arguments
If colArgs.Count = 0 Then
  ShowUsage
Else
  If colArgs.Count = 2 Then
    strComputer = colArgs(1)
  End If
' Connect with WMI service and StdRegProv class.
  Set objReg = GetObject _
   ("winmgmts:{impersonationLevel=impersonate}!\\" & _
     strComputer & "\root\default:StdRegProv")
  If Err = 0 Then
    If (LCase(colArgs(0)) = "/b") Or _
     (LCase(colArgs(0)) = "-b" ) Then
      AddBlock
    ElseIf (LCase(colArgs(0)) = "/u") Or _
     (LCase(colArgs(0)) = "-u") Then
      RemoveBlock
    Else
      ShowUsage
    End If
  Else
    WScript.Echo "Unable to connect to WMI service on " _
     & strComputer & "."
  End If
  Err.Clear
End If

'*************************************************************

Sub AddBlock

'Check whether WindowsUpdate subkey exists.
strParentPath = "SOFTWARE\Policies\Microsoft\Windows"
strTargetSubKey = "WindowsUpdate"
intCount = 0
intReturn1 = objReg.EnumKey(HKEY_LOCAL_MACHINE, _
 strParentPath, arrSubKeys)
If intReturn1 = 0 Then
  For Each strSubKey In arrSubKeys
    If strSubKey = strTargetSubKey Then
      intCount = 1
    End If
  Next
  If intCount = 1 Then
    SetValue
  Else
    WScript.Echo "Unable to find registry subkey " & _
     strTargetSubKey & ". Creating ..."
    intReturn2 = objReg.CreateKey(HKEY_LOCAL_MACHINE, _
     strKeyPath)
    If intReturn2 = 0 Then
      SetValue
    Else
      WScript.Echo "ERROR: Unable to create registry " & _
       "subkey " & strTargetSubKey & "."
    End If
  End If
Else
  WScript.Echo "ERROR: Unable to find registry path " & _
   strParentPath & "."
End If

End Sub

'*************************************************************

Sub SetValue

intReturn = objReg.SetDWORDValue(HKEY_LOCAL_MACHINE, _
 strKeyPath, strEntryName, dwValue)
If intReturn = 0 Then
  WScript.Echo "Added registry entry to block Windows XP " & _
   "SP2 deployment via Windows Update or Automatic Update."
Else
  WScript.Echo "ERROR: Unable to add registry entry to " & _
   "block Windows XP SP2 deployment via Windows Update " & _
   "or Automatic Update."
End If

End Sub

'*************************************************************

Sub RemoveBlock

intReturn = objReg.DeleteValue(HKEY_LOCAL_MACHINE, _
 strKeyPath, strEntryName)
If intReturn = 0 Then
  WScript.Echo "Deleted registry entry " & strEntryName & _
   ". Unblocked Windows XP SP2 deployment via Windows " & _
   "Update or Automatic Update."
Else
  WScript.Echo "Unable to delete registry entry " & _
   strEntryName & ". Windows XP SP2 deployment via " & _
   "Windows Update or Automatic Update is not blocked."
End If

End Sub

'*************************************************************

Sub ShowUsage

WScript.Echo "Usage:" & VbCrLf & _
 "  BlockXPSP2.vbs { /b | /u | /? } [hostname]" & VbCrLf & _
 "    /b = Block (deny) Windows XP Service Pack 2 " & _
 "deployment" & VbCrLf & _
 "    /u = Unblock (allow) Windows XP Service Pack 2 " & _
 "deployment" & VbCrLf & _
 "    /? = Show usage" & VbCrLf & _
 "    hostname = Optional. Name of remote computer. " & _
 "Default is local computer" & VbCrLf & _
 "Example:" & VbCrLf & _
 "  BlockXPSP2.vbs /b client1"

End Sub



Da Start > Esegui lancia blockxpsp2.vbs /u
Per ogni dubbio leggi qui:
http://www.microsoft.com/technet/script ... xpsp2.mspx
Avatar utente
Dylan666
Moderatore
 
Post: 38040
Iscritto il: 18/11/03 16:46

Postdi Locutus » 19/09/04 14:21

Grazie...

Ho eseguito lo script e pare che sia andato a modificare qualcosa...

Ma nonostante tutto mi propone sempre e solo aggionamenti per l'SP1...

C'è un modo per scaricarlo e installarlo offline? ;)
Locutus
Utente Senior
 
Post: 402
Iscritto il: 24/03/02 20:38
Località: Torino

Postdi Dylan666 » 19/09/04 16:24

Locutus ha scritto:Ma nonostante tutto mi propone sempre e solo aggionamenti per l'SP1...


Hai riavviato? Leggi la pagina che ho linkato, magari non ho trascritto bene qualcosa...

C'è un modo per scaricarlo e installarlo offline? ;)


http://www.pc-facile.com/forum/viewtopi ... +scaricare
Avatar utente
Dylan666
Moderatore
 
Post: 38040
Iscritto il: 18/11/03 16:46

Postdi Locutus » 19/09/04 18:52

Certo che ho riavviato...

ho fatto copia e incolla ;) poi il sistema mi ha dato conferma della rimozione di un qualcosa :D

Il service pack 2 nella versione di 250 l'ho scaricato, installato e il pc non mi si è più riavviato!!!

Azz che sfiga!!!

Meno male che avevo una copia immagine fatta appena ieri!!! :D
Locutus
Utente Senior
 
Post: 402
Iscritto il: 24/03/02 20:38
Località: Torino

Postdi Dylan666 » 19/09/04 19:27

Mentre installi lo SP2 hai tutti i programmi chiusi?
Sarebbe interessante sapere il messaggio preciso che appare dopo l'uso del VBS
Avatar utente
Dylan666
Moderatore
 
Post: 38040
Iscritto il: 18/11/03 16:46

Postdi Locutus » 19/09/04 21:17

Si, avevo chiuso tutto...

Per quanto riguarda il VBS, riavviandolo ti dico che mi torna un messaggio diverso dal precedente che dice:

Unable to delete registry entry DoNotAllowXSP2. Windows XP SP2 deployment via windows update or automatic update is not blocked...

Il messaggio mi pare chiaro...

Bah... :-?
Locutus
Utente Senior
 
Post: 402
Iscritto il: 24/03/02 20:38
Località: Torino

Postdi Dylan666 » 19/09/04 22:27

Perché bah? Il messaggio dice che non riesce a "sbloccare" lo SP2 in quanto non pare bloccato, ed è corretto dato che hai già usato lo script. Per rivedere la stessa frase della prima volta dovresti rimettere l'update di "bloccaggio" e poi rifare la procedura del VBS ;)
Avatar utente
Dylan666
Moderatore
 
Post: 38040
Iscritto il: 18/11/03 16:46

Postdi Locutus » 19/09/04 22:48

Ok, come da te suggerito ho rimesso e tolto...

La risposta è la seguente:

Deleted registry entry DoNotAllowXSP2. Unblocked Windows SP2 deployment via Windows Update or Automatic Update.

Il messaggio ancora una volta è "lapalis", pare che il blocco è stato tolto ed è la stessa risposta che ho avuto prima ma...

acqua la pippa!!! (niente da fare)

Ci rinuncio? :(
Locutus
Utente Senior
 
Post: 402
Iscritto il: 24/03/02 20:38
Località: Torino

Postdi Dylan666 » 19/09/04 22:56

Puoi lanciare la versione completa linkata prima.
Avatar utente
Dylan666
Moderatore
 
Post: 38040
Iscritto il: 18/11/03 16:46

Postdi Locutus » 19/09/04 23:04

Dylan666 ha scritto:Puoi lanciare la versione completa linkata prima.


Bè riproverò, come ho detto prima la precedente installazione della versione completa ha fatto si che XP non si avviasse più...

Però ancora non avevo lanciato lo script...

Lo farò domani in serata, vi terrò informati!!! ;)
Locutus
Utente Senior
 
Post: 402
Iscritto il: 24/03/02 20:38
Località: Torino

Postdi Locutus » 20/09/04 22:27

Fatto, tutto inutile, durante il riavvio dopo l'installazione della versione da 250 Mb la barra di progresso di xp si blocca e non si muove più...

Niente SP2 per me mi arrendo... :cry:
Locutus
Utente Senior
 
Post: 402
Iscritto il: 24/03/02 20:38
Località: Torino

Postdi Dylan666 » 20/09/04 23:37

Segnalalo nel topic dello SP2 può essere interessante ;)
Avatar utente
Dylan666
Moderatore
 
Post: 38040
Iscritto il: 18/11/03 16:46

Postdi Locutus » 21/09/04 05:43

Dylan666 ha scritto:Segnalalo nel topic dello SP2 può essere interessante ;)


Grazie... ;)
Locutus
Utente Senior
 
Post: 402
Iscritto il: 24/03/02 20:38
Località: Torino


Torna a Software Windows


Topic correlati a "Ho installato la XPSP2BlockerTools e adesso ho deciso...":


Chi c’è in linea

Visitano il forum: Nessuno e 12 ospiti